; Dwarven Appearances.ipt
; created 12/16/2015 8:11:41 PM
Table: DwarfAppearance
He is [@DwarfMaleAppearance]
She is [@DwarfFemaleAppearance]

Table: DwarfMaleAppearance
Set: Age={round({2d10 / 2})}
Set: HColor=[when]{Age}>{1d4 + 5}[do][@DwarfHairColorAged][else][@DwarfHairColor][end]
[#{Age} AgeText] [when]{Age}>{1d6 + 1d5 + 4}[do][|and is bald|with thinning [@DwarfMaleHairStyle]][else]with [@DwarfMaleHairStyle][end][when]{Age}>1[do] and [@DwarfMaleFacialHair][end], [@DwarfEyes] eyes, [@DwarfSkin] [@Skin], and [when]{Age}>3[do][@DwarfMaleBuild][else][@DwarfYouthBuild][end]. [when]{Age}>3[do][@DwarfMaleTattoos][else][@DwarfMaleTeenTattoos][end]

Table: DwarfFemaleAppearance
Set: Age={round({2d10 / 2})}
Set: HColor=[when]{Age}>{1d4 + 5}[do][@DwarfHairColorAged][else][@DwarfHairColor][end]
[#{Age} AgeText] with [@DwarfFemaleHairStyle][when]{Age}>2[do] and [@DwarfFemaleFacialHair][end], [@DwarfEyes] eyes, [@DwarfSkin] [@Skin], and [when]{Age}>3[do][@DwarfFemaleBuild][else][@DwarfYouthBuild][end]. [when]{Age}>3[do][@DwarfFemaleTattoos][else][@DwarfFemaleTeenTattoos][end]

Table: AgeText
Type: Lookup
1: a child ({1d6+6})
2: a teen ({12+1d3})
3: a teen ({15+1d4})
4-5: an adult ({19+1d80})
6-7: an adult ({100+1d99})
8-9: middle aged ({200+1d49})
10: old ({250+1d50})

Table: Skin
skin
skin tone
toned skin
complexion

Table: DwarfHairColor
black
brown
chestnut
auburn

Table: DwarfHairColorAged
graying [@DwarfHairColor]
gray
silver
white

Table: DwarfMaleHairStyle
unkempt {HColor} hair
long, braided {HColor} hair
long {HColor} hair
close-cropped {HColor} hair
short {HColor} hair
medium {HColor} hair

Table: DwarfFemaleHairStyle
unkempt {HColor} hair
long and tangled {HColor} hair
long, braided {HColor} hair
long {HColor} hair
shoulder-length {HColor} hair

Table: DwarfMaleFacialHair
\a neatly trimmed [@DwarfBeardColor] beard
\a [@DwarfBeardColor] mustache and chin beard
\a [@DwarfBeardColor] long chin beard
3:\a [@DwarfBeardColor] full beard
[@DwarfBeardColor] muttonchops and mustache
\a [@DwarfBeardColor] goatee
[@DwarfBeardColor] sidewhiskers and mustache
\a [@DwarfBeardColor] enormous mustache
2:\a [@DwarfBeardColor] long braided beard
[@DwarfBeardColor] braided sidewhiskers and beard

Table: DwarfFemaleFacialHair
\a [@DwarfBeardColor] full beard
\a [@DwarfBeardColor] chinstrap beard
\a [@DwarfBeardColor] sideburns
\a [@DwarfBeardColor] chin beard
\a [@DwarfBeardColor] neatly trimmed beard
4:no beard

Table: DwarfBeardColor
10:
4:lighter
4:darker
black
brown
chestnut
auburn
gray
white

Table: DwarfSkin
white
light brown
tanned
ruddy
dirty

Table: DwarfEyes
gray
blue
brown
hazel

Table: DwarfYouthBuild
is slender and small
is slender
is unusually small
is short
is pudgy
is tall (for a young dwarf)
is lanky
is overweight
is fat
is muscular
is short and stocky

Table: DwarfMaleBuild
a stocky build (4'{h=1d6+3}", {105+{5*{h}}+{3d16}} lbs)
is slender (4'{h=1d6+3}", {105+{5*{h}}-{3d16}} lbs)
is slight of build (4'{h=1d6+3}", {105+{5*{h}}-{3d16}} lbs)
a lean, muscular build (4'{h=1d6+3}", {105+{5*{h}}+{2d10-11}} lbs)
is short and lean (4'{h=1d4-1}", {105+{5*{h}}-{3d16}} lbs)
is a bit short (4'{h=1d4-1}", {105+{5*{h}}+{2d10-11}} lbs)
is quite short (3'{h=1d2+9}", {55+{5*{h}}+{2d10-11}} lbs)
is fat and very short (3'{h=1d2+9}", {55+{5*{h}}+{1d16+32}} lbs)
a medium build (4'{h=1d6+3}", {105+{5*{h}}+{2d10-11}} lbs)
is short and fat (4'{h=1d4-1}", {105+{5*{h}}+{1d16+32}} lbs)
is fat (4'{h=1d6+3}", {105+{5*{h}}+{1d16+32}} lbs)
is barrel-chested (4'{h=1d6+3}", {105+{5*{h}}+{3d16}} lbs)
is short and barrel-chested (4'{h=1d4-1}", {105+{5*{h}}+{3d16}} lbs)
is short and muscular (4'{h=1d4-1}", {105+{5*{h}}+{3d16}} lbs)
is muscular (4'{h=1d6+3}", {105+{5*{h}}+{3d16}} lbs)
is overweight (4'{h=1d6+3}", {105+{5*{h}}+{3d16}} lbs)
is tall and broad-shouldered (4'{h=1d5+6}", {105+{5*{h}}+{3d16}} lbs)
5:average height and build (4'{h=1d6+3}", {105+{5*{h}}+{2d10-11}} lbs)
is a bit taller than average (4'{h=1d4+6}", {105+{5*{h}}+{2d10-11}} lbs)
is rather tall (5'{h=1d3-1}", {165+{5*{h}}+{2d10-11}} lbs)
is extremely tall (5'{h=1d3}", {165+{5*{h}}+{2d10-11}} lbs)
is tall and lean (4'{h=1d5+6}", {105+{5*{h}}-{3d16}} lbs)
is tall and lanky (4'{h=1d5+6}", {105+{5*{h}}-{3d16}} lbs)

Table: DwarfFemaleBuild
a stocky build (4'{h=1d6+2}", {100+{5*{h}}+{3d16}} lbs)
is quite slender (4'{h=1d6+2}", {95+{5*{h}}-{3d16}} lbs)
is slight of build (4'{h=1d6+2}", {100+{5*{h}}-{3d16}} lbs)
is tall and lean (4'{h=1d5+5}", {100+{5*{h}}-{3d16}} lbs)
a lean figure (4'{h=1d6+2}", {100+{5*{h}}+{2d10-11}} lbs)
is short and lean (4'{h=1d3-1}", {100+{5*{h}}-{3d16}} lbs)
is a bit taller than average (4'{h=1d4+5}", {100+{5*{h}}+{2d10-11}} lbs)
is rather tall (5'{h=1d2-1}", {160+{5*{h}}+{2d10-11}} lbs)
is extremely tall (5'{h=1d2}", {160+{5*{h}}+{2d10-11}} lbs)
is short and curvy (4'{h=1d3-1}", {100+{5*{h}}+{3d16}} lbs)
is curvy (4'{h=1d6+2}", {100+{5*{h}}+{3d16}} lbs)
is short and muscular (4'{h=1d3-1}", {100+{5*{h}}+{3d16}} lbs)
is muscular (4'{h=1d6+2}", {100+{5*{h}}+{3d16}} lbs)
is a bit short (4'{h=1d2-1}", {100+{5*{h}}+{2d10-11}} lbs)
is quite short (3'{h=1d2+8}", {50+{5*{h}}+{2d10-11}} lbs)
a medium build (4'{h=1d6+2}", {100+{5*{h}}+{2d10-11}} lbs)
is short and round (4'{h=1d2-1}", {100+{5*{h}}+{3d16}} lbs)
is excessively fat (4'{h=1d6+2}", {100+{5*{h}}+{1d16+32}} lbs)
is pleasantly overweight (4'{h=1d6+2}", {100+{5*{h}}+{3d16}} lbs)
5:average height and build (4'{h=1d6+2}", {100+{5*{h}}+{2d10-11}} lbs)

Table: DwarfMaleTattoos
20:
2:He has a tattoo on his [|right|left] arm of [@DwarfTattooSubject].
2:He has tattoos on his arms of [!{1d2} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].
2:He has tattoos on his arms and chest of [!{1d3} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].
2:He has tattoos on his arms, chest, and neck of [!{1d4} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].
2:He has tattoos all over his body of [!{1d5} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].

Table: DwarfFemaleTattoos
20:
2:She has a tattoo on her [|right|left] arm of [@DwarfTattooSubject].
2:She has tattoos on her arms of [!{1d2} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].
2:She has tattoos on her arms and neck of [!{1d3} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].
2:She has tattoos on her arms, chest, and neck of [!{1d4} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].
2:She has tattoos all over her body of [!{1d5} DwarfTattooSubject >> implode] and [@DwarfTattooSubject].
 
Table: DwarfMaleTeenTattoos
30:
1:[when]{Age}>1[do]He has a tattoo on his [|right|left] arm of [@DwarfTattooSubject].[end]
1:[when]{Age}>1[do]He has a tattoo on his chest of [@DwarfTattooSubject].[end]
1:[when]{Age}>1[do]He has a tattoo on his neck of [@DwarfTattooSubject].[end]

Table: DwarfFemaleTeenTattoos
30:
1:[when]{Age}>1[do]She has a tattoo on his [|right|left] arm of [@DwarfTattooSubject].[end]
1:[when]{Age}>1[do]She has a tattoo on his chest of [@DwarfTattooSubject].[end]
1:[when]{Age}>1[do]She has a tattoo on his neck of [@DwarfTattooSubject].[end]

Table: DwarfTattooSubject
\a [|||||bloody|broken|flaming|glowing|ornate|rune-covered] sword
\a [|||||bloody|broken|flaming|glowing|ornate|rune-covered] dagger
\a [|||||bloody|broken|flaming|glowing|ornate|rune-covered] mace
\a [|||||bloody|broken|flaming|glowing|ornate|rune-covered] [||double-headed] axe
\a [|||||bloody|broken|flaming|glowing|ornate|rune-covered] [||war]hammer
\a [|||||bloody|broken|flaming|glowing|ornate|rune-covered] spear
\a [|||||broken|flaming|glowing|ornate|rune-covered] crossbow
a quiver of bolts
crossed [|||||bloody|flaming|glowing|ornate|rune-covered] axes
crossed [|||||bloody|flaming|glowing|ornate|rune-covered] [||war]hammers
crossed [|||||bloody|flaming|glowing|ornate|rune-covered] swords
a [||||flaming|broken] skull
a [||||glowing] shield
a wolf
a hawk
a dragon
an armored [|dwarf|figure]
a storm
mountains
an anvil
a tool of the trade
a stone fist
a sealed box
a gemstone
fire
a fire in a hearth
a forge
a circular labyrinth
twelve hammers in a circle
six hexagons
an elaborate piece of jewelry (as if worn)
a chest of treasure
a keg or barrel
a tankard of ale
a map
roots of a tree
runes
an ancient abstract design
writing in an ancient unknown language