// Family relationships

Prompt: Type {Child|YoungAdult|Adult|Mature} Child

Table: Family
[@{$prompt1}Family]

Table: MatureFamily
Set: numsibs={1d3+1d2+1d2-2}
2:Unmarried, living [@LivingWith]
1:Unmarried, but has a young [|son|daughter], living [@LivingWith]
3:Previously married, but spouse [@Fate]. Has [@Children]. Living [@LivingWith]
3:Previously married, but spouse [@Fate]. Living [@LivingWith]
5:Married. Has [@Children]. Living [@LivingWith]

Table: AdultFamily
Set: numsibs={1d3+1d2-1}
2:Unmarried, living [@LivingWith]
1:Unmarried, but has a young [|son|daughter], living [@LivingWith]
2:Previously married, but spouse [@Fate]. Has [@Children]. Living [@LivingWith]
2:Previously married, but spouse [@Fate].  Living [@LivingWith]
4:Married. Has [@Children]. Living [@LivingWith]

Table: YoungAdultFamily
Set: numsibs={1d3}
2:Unmarried, living [@LivingWith]
2:Unmarried, but has a young [|son|daughter], living [@LivingWith]
1:Previously married, but spouse [@Fate]. Has [@Children]. Living [@LivingWith]
1:Previously married, but spouse [@Fate].  Living [@LivingWith]
2:Married. Has [@Children]. Living [@LivingWith]

Table: ChildFamily
Set: numsibs={1d3+1d2+1d2-2}
1:Lives [@ChildLivingWith] [@Siblings]. Father [@Fate] and mother [|died in childbirth|[@Fate]].
1:Lives with mother, [@Siblings]. Father [@Fate].
1:Lives with father, [@Siblings]. Mother [|died in childbirth|[@Fate]].
3:Lives with parents, [@Siblings].
2:Lives with parents and grandparents, [@Siblings].
2:Lives with parents and [|grandmother|grandfather], [@Siblings].

Table: ChildLivingWith
alone with
with an unrelated [|same sex|same sex|opposite sex] adult,
with an unrelated [|same sex|same sex|opposite sex] adult who is [@LivingWithFamily],
with grandparents,
with grandmother,
with grandfather,
with adult brother who is [@LivingWithFamily] Has
with adult sister who is [@LivingWithFamily] Has

Table: LivingWith
alone.
with an unrelated [|same sex|same sex|opposite sex] adult.
with grandparents.
with grandmother.
with grandfather.
with adult brother who is [@LivingWithFamily]
with adult sister who is [@LivingWithFamily]

Table: LivingWithFamily
Set: numsibs={1d3+1d2-1}
2:unmarried.
1:unmarried with a young [|son|daughter].
2:previously married, but spouse [@Fate], with [@Children].
2:previously married, but spouse [@Fate].
4:married, with [@Children].

Table: Fate
died of disease
died in \a [|orc|kobold|goblin|animal|monster] attack
disappeared [|mysteriously|into the wilderness]
was executed for [|crimes|dark magic|heresy|banditry]
moved to another town or village [|for an apprenticeship|to (re)marry|to get away from someone|to run away from family|to escape a bad situation]
passed away due to poor health
joined a religious order
joined the military [|and is still serving|and was killed in battle|and mustered out but lives elsewhere]
is a wanted criminal [|for banditry|for dark magic|for heresy|for murder|for theft|for terrible crimes|for horse theft|for insurrection|for attacking a noble|for arson|for innumerable crimes|for one drunken mistake|for a killing that was in self-defense]

Table: Siblings
Set: brothers={1d{$numsibs+1}-1}
no siblings
no siblings in household, one [|brother|sister] [@Fate]
one [|brother|sister]
[#{brothers} BrotherSister]
[#{brothers} BrotherSister]. One [|brother|sister] [@Fate]
[#{brothers} BrotherSister] and an unrelated [|male|female] orphan whose [|father|mother|father|mother|parents|parents|grandparents|grandmother|grandfather|aunt|uncle] [@Fate]

Table: BrotherSister
Type: Lookup
0:[when]{numsibs}>0[do]{numsibs} sisters[end]
1:1 brother[when]{numsibs-1}>0[do] and {numsibs-1} sisters[end]
2:2 brothers[when]{numsibs-2}>0[do] and {numsibs-2} sisters[end]
3:3 brothers[when]{numsibs-3}>0[do] and {numsibs-3} sisters[end]
4:4 brothers[when]{numsibs-4}>0[do] and {numsibs-4} sisters[end]
5:5 brothers[when]{numsibs-5}>0[do] and {numsibs-5} sisters[end]
6:6 brothers[when]{numsibs-6}>0[do] and {numsibs-6} sisters[end]
7:7 brothers[when]{numsibs-7}>0[do] and {numsibs-7} sisters[end]

Table: Children
Set: brothers={1d{$numsibs+1}-1}
no children
no children in household, one [|son|daughter] [@Fate]
one [|son|daughter]
[#{brothers} SonDaughter]
[#{brothers} SonDaughter], and one [|son|daughter] who [@Fate]
[#{brothers} SonDaughter] and an unrelated [|male|female] orphan whose [|father|mother|father|mother|parents|parents|grandparents|grandmother|grandfather|aunt|uncle] [@Fate]

Table: SonDaughter
Type: Lookup
0:[when]{numsibs}>0[do]{numsibs} daughters[end]
1:1 son[when]{numsibs-1}>0[do] and {numsibs-1} daughters[end]
2:2 sons[when]{numsibs-2}>0[do] and {numsibs-2} daughters[end]
3:3 sons[when]{numsibs-3}>0[do] and {numsibs-3} daughters[end]
4:4 sons[when]{numsibs-4}>0[do] and {numsibs-4} daughters[end]
5:5 sons[when]{numsibs-5}>0[do] and {numsibs-5} daughters[end]
6:6 sons[when]{numsibs-6}>0[do] and {numsibs-6} daughters[end]
7:7 sons[when]{numsibs-7}>0[do] and {numsibs-7} daughters[end]