// Random murder generator
// Based on data from https://www.cam.ac.uk/research/news/murder-map-reveals-medieval-londons-meanest-streets
// Historically accurate data for 14th century London
// Implemented by Jonathan Dale
// This generator will generate one year of random murders for a city or town of the specified population.
Prompt: Population {} 50000
Define: pop={$prompt1}
Maxreps:1
Header: This year in your city or town, the following murders occurred:
Table: Murders
[@{round({$pop}/{1d3000+3300})} Murder]
Table: Murder
The victim was killed by [@Perpetrator] [|on [@DayOfWeek] [@TimeOfDay]|[@TimeOfDay] on [@DayOfWeek]]. [|They were|The attack occurred|The victim was] [@Location]. The victim was [@Weapon], [@TimeOfDeath].
The victim was [@Weapon] by [@Perpetrator], [|on [@DayOfWeek] [@TimeOfDay]|[@TimeOfDay] on [@DayOfWeek]], [@Location], [@TimeOfDeath].
Table: DayOfWeek
211:Monday
70:Tuesday
99:Wednesday
99:Thursday
106:Friday
106:Saturday
310:Sunday
Table: TimeOfDay
21:around daybreak
14:in the morning
14:[|around midday|in the afternoon]
310:in the early evening
458:in the late evening
99:at night
85:
Table: Location
528:[|on the street|on the street|in an alley|in a public square]
99:in an unspecified public space
21:[|in a market stall|in a shop|in a place of business]
28:[|on a wharf|by the river|by the water]
42:in a tavern
14:in a brothel
42:in a church or other religious building
7:in a prison
85:in the perpetrator's residence
70:in the victim's residence
56:in a residence other than that of the victim or perpetrator
7:in an unknown location
Table: Weapon
14:struck [@WoundLocation] with an axe
359:[|stabbed|slashed|struck] [@WoundLocation] with a long knife
204:[|stabbed|slashed|struck] [@WoundLocation] with a short knife
120:[|stabbed|slashed|struck] [@WoundLocation] with a sword
190:struck [@WoundLocation] with a staff
7:shot [@WoundLocation] with a [|bow|bow|crossbow]
77:[|punched|strangled|kicked|throttled|choked]
7:struck [@WoundLocation] with a rock
14:drowned
7:killed by uncertain means
Table: WoundLocation
352:in the head
21:in the neck
49:in the throat
63:in the hands, arms, and shoulders
239:in the chest
28:in the back
99:in the lower abdomen
14:in the legs
77:multiple times in different locations
Table: TimeOfDeath
324:and died immediately
63:and died within 2 hours
92:and died after {1d5+1} hours
42:and died after {1d7+5} hours
77:and died after {1d13+11} hours
63:and died two days later
70:and died {1d2+2} days later
63:and died {1d2+4} days later
42:and died one week later
106:and died {1d3+1} weeks later
35:and died more than a month later
Table: PerpGender
92:male
8:female
Table: Perpetrator
5:[|a noble|a chamberlain|a wealthy merchant|a knight][@Accomplices]
3:a [@PerpGender] goldsmith[@Accomplices]
3:a [@PerpGender] baker[@Accomplices]
3:a [@PerpGender] tailor[@Accomplices]
3:a [@PerpGender] fishmonger[@Accomplices]
2:a [@PerpGender] brewer[@Accomplices]
2:a [@PerpGender] carpenter[@Accomplices]
2:a [@PerpGender] cobbler[@Accomplices]
2:a [@PerpGender] skinner[@Accomplices]
2:a [@PerpGender] craftsman[@Accomplices]
15:a [@PerpGender] servant[@Accomplices]
11:[|a [@PerpGender] priest|a [@PerpGender] cleric|a [@PerpGender] chaplain][@Accomplices]
5:[|a [@PerpGender] beggar|a [@PerpGender] purse-cutter|a [@PerpGender] prostitute][@Accomplices]
12:[|a [@PerpGender] child|a [@PerpGender] adolescent][@Accomplices]
Table: VictimAge
77:a child or adolescent
923:an adult
Table: Accomplices
66:
10: and one [|accomplice|brother|family member]
8: and 2 [|accomplices|brothers|family members]
6: and 3 [|accomplices|brothers|family members]
4: and 4 [|accomplices|brothers|family members]
5: and {1d6+4} [|accomplices|brothers|family members]